Microsoft Store 即微软应用商店虽然鸡肋，但架不住有时候还真就得它不可。有些软件，比如 UWP，还真只能从它这里下。不过吧，国内版大家都知道问题也不是一般的多，比较典型的如应用商店 0x80248014 报错，直接焊死大门让你用不了。

接下来咱们就来唠唠微软应用商店 0x80248014 该如何解决。

初步排查

在尝试更深入的解决方法之前，我们首先进行一些基本的排查步骤，以确定是否有任何小故障可能暂时阻止了微软商店应用的打开。这些步骤包括：

• 关闭系统上正在运行的其他应用程序，特别是那些可能干扰微软商店运行的安全软件。
• 尝试重启Windows个人电脑，以解决操作系统层面可能出现的临时问题。
• 利用Windows的搜索功能，尝试直接打开微软商店应用。

若初步排查未能解决问题，我们接下来可以尝试修复和重置微软商店应用，以解决可能存在的临时故障并修复受损的文件。以下是详细的操作步骤：

修复微软商店应用

• 打开“设置”：通过右键点击“开始”按钮，在弹出的菜单中选择“设置”选项。
• 访问“系统”：在“设置”界面中，找到并点击“系统”选项，进入系统设置。
• 查找并点击“系统组件”：在左侧的列表中，定位并单击“系统组件”选项，进入相关设置。

接下来，根据不同的系统版本和情况，你可能需要执行不同的操作来修复或重置微软商店应用。请注意，这些步骤可能因操作系统版本和个人电脑配置的不同而有所差异。如果你在执行过程中遇到困难，建议查阅相关的微软官方文档或寻求专业的技术支持。

在系统组件列表中，定位并点击微软商店应用旁边的三个水平点，以打开其相关设置。接着，在弹出的菜单中选择“高级选项”，以进入更深入的修复和重置选项。请注意，这些步骤可能因系统版本和配置的不同而有所差异，因此在实际操作时请根据具体情况进行调整。

进行修复操作：在高级选项页面中，向下滚动并找到“修复”按钮，点击进行修复。请注意，此操作不会对您的应用数据造成影响。

重置微软商店应用

若修复操作未奏效，你可尝试对微软商店应用进行重置：

• 仍于“高级选项”页面内，寻找到并点击“修复”按钮下方的“重置”选项。
• 在随后的确认弹窗中，点击“重置”以确认执行此操作。

请注意，重置微软商店应用将重置所有设置、清除登录信息，并删除所有应用数据。在执行此操作前，请务必备份重要数据。

若上述步骤仍未能解决问题，或许需要进一步深入排查，如核查系统文件的完整性或更新操作系统。同时，确认时间和日期设置无误也至关重要，因为错误的时间和日期设置可能导致应用异常。请打开“设置”，进入“时间和语言”中的“日期和时间”设置，确保时区选择正确并开启“自动设置时间”功能。

检查网络连接

稳定的网络是微软商店能够顺畅打开的关键。请先确认设备已成功连接至互联网，并尝试重新连接以解决问题。同时，断开与同一网络的其他设备的连接，重启路由器可能有助于改善网络状况。

清除微软商店缓存

缓存问题常常导致微软商店应用出现故障。你可以通过按下Win+R键打开“运行”对话框，输入wsreset并点击“确定”，来清除微软商店的缓存。清除后，重新启动微软商店，看看问题是否得到解决。

这将启动一个空白的Windows命令提示符窗口，表明正在清除微软商店的缓存。请耐心等待大约30秒，直至该过程完全结束。

关闭代理服务

代理设置有时会干扰某些应用程序和服务的正常运行。为了解决这一问题，请进入“设置”>“网络和互联网”>“代理”，然后关闭代理服务。

安装可用的Windows更新

确保您的Windows系统已安装最新的更新，这有助于修复微软商店应用可能遇到的问题。请打开“设置”>“Windows更新”，检查并安装任何可用的更新。

重新安装微软商店

如果常规的修复方法均无法解决问题，您可以尝试卸载并重新安装微软商店。请注意，此操作将移除关键的Windows组件，因此应谨慎进行。与普通应用程序不同，微软商店的卸载和安装过程需要特殊的操作步骤。以下是指南：

卸载微软商店应用

首先，打开PowerShell。您可以在Windows搜索中输入“PowerShell”来找到并运行它。接着，以管理员身份运行PowerShell，并在用户账户控制窗口中选择“是”以确认操作。在PowerShell窗口中，粘贴并执行以下命令以卸载微软商店：

Get-AppxPackage WindowsStore | Remove-AppxPackage

重启设备

成功执行卸载命令后，请关闭PowerShell并重启您的计算机。

重新安装微软商店应用

设备重启后，再次以管理员身份运行PowerShell，并在窗口中粘贴执行以下命令以重新安装微软商店：

Get-AppxPackage -AllUsers | Foreach {Add-AppxPackage -DisableDevelopmentMode -Register "$($_.InstallLocation)\AppXManifest.xml"}

请注意，这些步骤可能因Windows版本的不同而有所差异。在执行任何操作之前，请确保您已备份重要数据，以防意外发生。

重新安装微软商店

在执行上述操作后，您可能需要重新安装微软商店应用。请注意，这可能会影响您已安装的其他应用程序，因此在操作完成后，请仔细检查并重新安装可能受到影响的程序。如果您在执行这些步骤时遇到任何困难，建议联系微软官方支持以获取专业帮助。

应用商店 0x80248014 报错解决办法

重置微软商店权限

Win+X 打开菜单，找到并单击打开“Windows Powershell（管理员）”输入以下命令并回车：

重置 Windows 更新组件

以上方法没能解决应用商店 0x80248014 错误，就来试试以下命令：

注意：以上命令需逐条输入逐条回车执行，切勿直接全部复制运行；全部执行完毕后请重启电脑。

重置 Windows 更新组件（进阶）

如果以上方法均无效，那么小江只能祭出杀招了，以下方法由国外玩家使用后证明有效。

注意：该方法适用于Win10，Win11未经测试；执行以下脚本后电脑会重启，请提前保存好资料。

@echo off
:: Created by: Shawn Brink
:: Created on: October 1, 2015
:: Updated on: March 8, 2021
:: Tutorial: https://www.tenforums.com/tutorials/24742-reset-windows-update-windows-10-a.html
:: Prompt to Run as administrator
Set "Variable=0" & if exist "%temp%\getadmin.vbs" del "%temp%\getadmin.vbs"
fsutil dirty query %systemdrive%  >nul 2>&1 && goto :(Privileges_got)
If "%1"=="%Variable%" (echo. &echo. Please right-click on the file and select &echo. "Run as administrator". &echo. Press any key to exit. &pause>nul 2>&1& exit)
cmd /u /c echo Set UAC = CreateObject^("Shell.Application"^) : UAC.ShellExecute "%~0", "%Variable%", "", "runas", 1 > "%temp%\getadmin.vbs"&cscript //nologo "%temp%\getadmin.vbs" & exit
:(Privileges_got)
:: Checking and Stopping the Windows Update services
set b=0
:bits
set /a b=%b%+1
if %b% equ 3 (
   goto end1
) 
net stop bits
echo Checking the bits service status.
sc query bits | findstr /I /C:"STOPPED" 
if not %errorlevel%==0 ( 
    goto bits 
) 
goto loop2
:end1
cls
echo.
echo Cannot reset Windows Update since "Background Intelligent Transfer Service" (bits) service failed to stop. Please restart the computer, and try again.
echo.
pause
goto Start
:loop2
set w=0
:wuauserv
set /a w=%w%+1
if %w% equ 3 (
   goto end2
) 
net stop wuauserv
echo Checking the wuauserv service status.
sc query wuauserv | findstr /I /C:"STOPPED" 
if not %errorlevel%==0 ( 
    goto wuauserv 
) 
goto loop3
:end2
cls
echo.
echo Cannot reset Windows Update since "Windows Update" (wuauserv) service failed to stop. Please restart the computer, and try again.
echo.
pause
goto Start
:loop3
set app=0
:appidsvc
set /a app=%app%+1
if %app% equ 3 (
   goto end3
) 
net stop appidsvc
echo Checking the appidsvc service status.
sc query appidsvc | findstr /I /C:"STOPPED" 
if not %errorlevel%==0 ( 
    goto appidsvc 
) 
goto loop4
:end3
cls
echo.
echo Cannot reset Windows Update since "Application Identity" (appidsvc) service failed to stop. Please restart the computer, and try again.v
echo.
pause
goto Start
:loop4
set c=0
:cryptsvc
set /a c=%c%+1
if %c% equ 3 (
   goto end4
) 
net stop cryptsvc
echo Checking the cryptsvc service status.
sc query cryptsvc | findstr /I /C:"STOPPED" 
if not %errorlevel%==0 ( 
    goto cryptsvc 
) 
goto Reset
:end4
cls
echo.
echo Cannot reset Windows Update since "Cryptographic Services" (cryptsvc) service failed to stop. Please restart the computer, and try again.
echo.
pause
goto Start
:Reset
Ipconfig /flushdns
del /s /q /f "%ALLUSERSPROFILE%\Application Data\Microsoft\Network\Downloader\qmgr*.dat" 
del /s /q /f "%ALLUSERSPROFILE%\Microsoft\Network\Downloader\qmgr*.dat"
del /s /q /f "%SYSTEMROOT%\Logs\WindowsUpdate\*"
if exist "%SYSTEMROOT%\winsxs\pending.xml.bak" del /s /q /f "%SYSTEMROOT%\winsxs\pending.xml.bak" 
if exist "%SYSTEMROOT%\winsxs\pending.xml" ( 
    takeown /f "%SYSTEMROOT%\winsxs\pending.xml" 
    attrib -r -s -h /s /d "%SYSTEMROOT%\winsxs\pending.xml" 
    ren "%SYSTEMROOT%\winsxs\pending.xml" pending.xml.bak 
) 
if exist "%SYSTEMROOT%\SoftwareDistribution.bak" rmdir /s /q "%SYSTEMROOT%\SoftwareDistribution.bak"
if exist "%SYSTEMROOT%\SoftwareDistribution" ( 
    attrib -r -s -h /s /d "%SYSTEMROOT%\SoftwareDistribution" 
    ren "%SYSTEMROOT%\SoftwareDistribution" SoftwareDistribution.bak 
) 
if exist "%SYSTEMROOT%\system32\Catroot2.bak" rmdir /s /q "%SYSTEMROOT%\system32\Catroot2.bak" 
if exist "%SYSTEMROOT%\system32\Catroot2" ( 
    attrib -r -s -h /s /d "%SYSTEMROOT%\system32\Catroot2" 
    ren "%SYSTEMROOT%\system32\Catroot2" Catroot2.bak 
) 
:: Reset Windows Update policies
reg delete "HKCU\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate" /f
reg delete "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\WindowsUpdate" /f
reg delete "HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate" /f
reg delete "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\WindowsUpdate" /f
gpupdate /force
:: Reset the BITS service and the Windows Update service to the default security descriptor
sc.exe sdset bits D:(A;;CCLCSWRPWPDTLOCRRC;;;SY)(A;;CCDCLCSWRPWPDTLOCRSDRCWDWO;;;BA)(A;;CCLCSWLOCRRC;;;AU)(A;;CCLCSWRPWPDTLOCRRC;;;PU)
sc.exe sdset wuauserv D:(A;;CCLCSWRPWPDTLOCRRC;;;SY)(A;;CCDCLCSWRPWPDTLOCRSDRCWDWO;;;BA)(A;;CCLCSWLOCRRC;;;AU)(A;;CCLCSWRPWPDTLOCRRC;;;PU)
:: Reregister the BITS files and the Windows Update files
cd /d %windir%\system32
regsvr32.exe /s atl.dll 
regsvr32.exe /s urlmon.dll 
regsvr32.exe /s mshtml.dll 
regsvr32.exe /s shdocvw.dll 
regsvr32.exe /s browseui.dll 
regsvr32.exe /s jscript.dll 
regsvr32.exe /s vbscript.dll 
regsvr32.exe /s scrrun.dll 
regsvr32.exe /s msxml.dll 
regsvr32.exe /s msxml3.dll 
regsvr32.exe /s msxml6.dll 
regsvr32.exe /s actxprxy.dll 
regsvr32.exe /s softpub.dll 
regsvr32.exe /s wintrust.dll 
regsvr32.exe /s dssenh.dll 
regsvr32.exe /s rsaenh.dll 
regsvr32.exe /s gpkcsp.dll 
regsvr32.exe /s sccbase.dll 
regsvr32.exe /s slbcsp.dll 
regsvr32.exe /s cryptdlg.dll 
regsvr32.exe /s oleaut32.dll 
regsvr32.exe /s ole32.dll 
regsvr32.exe /s shell32.dll 
regsvr32.exe /s initpki.dll 
regsvr32.exe /s wuapi.dll 
regsvr32.exe /s wuaueng.dll 
regsvr32.exe /s wuaueng1.dll 
regsvr32.exe /s wucltui.dll 
regsvr32.exe /s wups.dll 
regsvr32.exe /s wups2.dll 
regsvr32.exe /s wuweb.dll 
regsvr32.exe /s qmgr.dll 
regsvr32.exe /s qmgrprxy.dll 
regsvr32.exe /s wucltux.dll 
regsvr32.exe /s muweb.dll 
regsvr32.exe /s wuwebv.dll
regsvr32.exe /s wudriver.dll
netsh winsock reset
netsh winsock reset proxy
:: Set the startup type as automatic
sc config wuauserv start= auto
sc config bits start= auto 
sc config DcomLaunch start= auto 
:Start
net start bits
net start wuauserv
net start appidsvc
net start cryptsvc
:: Restart computer
cls
echo It is required to restart the computer to finish resetting Windows Update.
echo.
echo Please save and close anything open now, before the computer is restarted.
echo.
pause
echo.
echo.
echo.
echo *** Restart computer now. ***
echo.
pause
shutdown /r /f /t 0

1、复制上方代码，保存为.bat脚本（在新打开的页面右键另存为，并将.txt改为.bat），双击打开，必要时以管理员身份运行；

2、如未遭遇异常在全部操作执行完毕后电脑会自行关机重启；

3、如遭遇异常无法执行命令，会提示按下任意键以继续，按下任意键后.bat 文件将重新启之前已停止的服务而不会重启电脑。